***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*OCT 23, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5946V-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     0.849
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=146.8  VTO=3.88  LEVEL=3  VMAX=1e5  ETA=0.006  nfs=1.246e12  gamma=1.55)
Rd     d1    d2    4.3m TC=3.7m,10u
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=44  TBV1=5.555e-4   CJO=2.647e-9  M=1.253  VJ=9.097)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=2.850e-20  N=5.298e-1  RS=12.04u  EG=1.1  TT=20n ikf=1.120e-3)
Rdiode  d1  21    6.114e-3 TC=2.2m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   4.315e-10
.MODEL     DGD    D(M=1.929   CJO=4.315e-10   VJ=8.676)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    2.62097e-9
.ENDS
*$
